[VB6] Autorun: Ausführen beim Systemstart

Möchten Sie, dass beim Starten von Windows eine bestimmte Anwendung geladen wird? Hierbei kann es sich z.B. um einen Terminkalender handeln, welcher Sie auf fällige Termine oder Geburtstage hinweist. Oder auch ihr Programm selbst, sozusagen einen Autostart für das Ausführen der Software, sobald Windows startet.

Der nachfolgende Code zeigt, wie man eine bestimmte Anwendung direkt in die Windows-Registrier-Datenbank einträgt, so dass diese beim Windows-Start automatisch geladen wird. Über eine entsprechende Prozedur kann der Eintrag auch wieder aus der Registrier-Datenbank gelöscht werden.

Am besten den Quellcode in ein Modus kopieren:

' zunächst die benötigten API-Deklarationen
Private Declare Function RegOpenKeyEx Lib "advapi32.dll" _
  Alias "RegOpenKeyExA" ( _
  ByVal hKey As Long, _
  ByVal lpSubKey As String, _
  ByVal ulOptions As Long, _
  ByVal samDesired As Long, _
  phkResult As Long) As Long
 
Private Declare Function RegCloseKey Lib "advapi32.dll" ( _
  ByVal hKey As Long) As Long
 
Private Declare Function RegSetValueEx_String Lib "advapi32.dll" _
  Alias "RegSetValueExA" ( _
  ByVal hKey As Long, _
  ByVal lpValueName As String, _
  ByVal Reserved As Long, _
  ByVal dwType As Long, _
  ByVal lpData As String, _
  ByVal cbData As Long) As Long
 
Private Declare Function RegDeleteValue Lib "advapi32.dll" _
  Alias "RegDeleteValueA" ( _
  ByVal hKey As Long, _
  ByVal lpValueName As String) As Long
 
Public Const HKEY_CURRENT_USER = &H80000001
Public Const HKEY_LOCAL_MACHINE = &H80000002
 
Const KEY_QUERY_VALUE = &H1
Const KEY_SET_VALUE = &H2
Const KEY_CREATE_SUB_KEY = &H4
Const KEY_ENUMERATE_SUB_KEYS = &H8
Const KEY_NOTIFY = &H10
Const KEY_CREATE_LINK = &H20
Const KEY_ALL_ACCESS = KEY_QUERY_VALUE Or KEY_SET_VALUE _
  Or KEY_CREATE_SUB_KEY Or KEY_ENUMERATE_SUB_KEYS Or _
  KEY_NOTIFY Or KEY_CREATE_LINK
 
Const ERROR_SUCCESS = 0&
 
Const REG_NONE = 0
Const REG_SZ = 1
 
' Anwendung in Registry eintragen
' 
' sDescr:  Beschreibung/Bezeichnung
' sPath :  Pfad inkl. Dateiname der Anwendung
' ===========================================
Public Function SetAutoRun(sDescr As String, _
  sPath As String) As Boolean
 
  Dim lResult As Long
  Dim KeyHandle As Long
  Dim Key As String
 
  Const root = HKEY_CURRENT_USER
  Key = "SOFTWARE\Microsoft\Windows\CurrentVersion\Run"
 
  lResult = RegOpenKeyEx(root, Key, 0, KEY_ALL_ACCESS, _
    KeyHandle)
  If lResult <> ERROR_SUCCESS Then
    SetAutoRun = False
    Exit Function
  End If
 
  ' +1 für die Null am Ende
  lResult = RegSetValueEx_String(KeyHandle, sDescr, 0, _
    REG_SZ, sPath, Len(sPath) + 1)
 
  RegCloseKey KeyHandle
  SetAutoRun = (lResult = ERROR_SUCCESS)
End Function
 
' aus Registry entfernen
' 
' sDescr:  Beschreibung/Bezeichnung
' =================================
Function RemoveAutoRun(sDescr As String) As Boolean
  Dim lResult As Long
  Dim KeyHandle As Long
  Dim Key As String
 
  Const root = HKEY_CURRENT_USER
  Key = "SOFTWARE\Microsoft\Windows\CurrentVersion\Run"
 
  lResult = RegOpenKeyEx(root, Key, 0, _
    KEY_ALL_ACCESS, KeyHandle)
  If lResult <> ERROR_SUCCESS Then
    RemoveAutoRun = False
    Exit Function
  End If
  lResult = RegDeleteValue(KeyHandle, sDescr)
  RemoveAutoRun = (lResult = ERROR_SUCCESS)
  RegCloseKey KeyHandle
End Function

Beispiel:
Beim Starten von Windows soll automatisch Notepad (Texteditor) gestartet werden.

If SetAutoRun("Notepad", "c:\windows\notepad.exe") Then
  MsgBox "Eintrag war erfolgreich."
Else
  MsgBox "Eintrag war nicht erfolgreich."
End If
 
' Eintrag wieder aus Registry löschen
RemoveAutoRun "Notepad"